--===========================================================================--
-- TABLES temporelles  /   MS Cloud Summit 2017   /  2017-01-09  version 1.0 --
--===========================================================================--
-- Fred Brouard, SQLpro -  http://sqlpro.developpez.com - SQLpro@SQLspot.com --
-- Arian papillon -        http://www.datafly.fr/ -   a.papillon@datafly.com --
--===========================================================================--

--▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄--
-- Exemples 3 : Déplacement du stockage pour la table d'historisation                        --
--▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀--

USE  DB_TEMPORAL;
GO

-------------------------------------------------------------------------------
-- création d'une table
-------------------------------------------------------------------------------

CREATE TABLE Tempo8
(
ID INT IDENTITY CONSTRAINT PK_tempo8 PRIMARY KEY,
DATA5 VARCHAR(32),
_DH_DEB DATETIME2 GENERATED ALWAYS AS ROW START HIDDEN NOT NULL,
_DH_FIN DATETIME2 GENERATED ALWAYS AS ROW END   HIDDEN NOT NULL,
PERIOD FOR SYSTEM_TIME (_DH_DEB, _DH_FIN)
)
WITH (SYSTEM_VERSIONING = ON (HISTORY_TABLE = dbo.Tempo8_histo));
GO

EXEC sp_configure 'xp_cmdshell', 1;
GO
RECONFIGURE;
GO
EXEC xp_cmdshell 'MKDIR "C:\DB_temporal"';
GO

ALTER DATABASE DB_TEMPORAL
   ADD FILEGROUP FG_HISTO;
GO

ALTER DATABASE DB_TEMPORAL
   ADD FILE (NAME = 'F_HISTO',
             FILENAME = 'C:\DB_temporal\temporal_DB.ndf', 
             SIZE = 100 MB, 
             FILEGROWTH = 10MB)
   TO FILEGROUP FG_HISTO;
GO

-- déplacement de la table d'historique vers le nouveau storage
CREATE CLUSTERED INDEX ix_Tempo8_histo
   ON dbo.Tempo8_histo(ID)
WITH (DROP_EXISTING = ON)
ON FG_HISTO;
GO